CivilFEM:拉压杆实例

下图所示桁架，受集中荷载作用，螺栓孔洞面积3cm²，采用欧洲规范3，构件为L型钢，规格为120×120×12。

几何尺寸：

a=1.0m；

b=0.5m；

荷载：

P=300kN

FINISH
~CFCLEAR,,1 ! Not needed
! 标题
/TITLE,CivilFEM Example 0602. Tension and Compression
! CivilFEM Setup: Code & Units 选择规范和单位
~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,KN
~CODESEL,EC3,EC2,,,EC8! Eurocodes
/PREP7
! CivilFEM Preprocessor
! --------------------------------------------------
! Materials 定义材料
! Mat 1: Fe430
~CFMP,1,LIB,STEEL,EC3,Fe 430,0,0,0
! Element Types 定义单元类型
ET,1,LINK1 ! Type 1: 2D Spar
! Sections 定义截面
~SSECLIB,1,1,23,11 !L 120 x 120 x 12
! Code Properties 下面这段命令设置梁上开口的面积
~SECMDF,1,EC3PROP ,AHOLES ,,3e-004,0,0,0
! Beam & Shell properties
~BMSHPRO,1,BEAM,1,1,,,1,1,0, ! Beam Property
! Ansys Preprocessor
! --------------------------------------------------
! Nodes
N, 1 $ N,2,1 $ N,3,,-0.5
! Elements
E,1,2
E,3,2
EPLOT
/SOLU
! Ansys Solution
! --------------------------------------------------
! Displacements
D, 1,ALL
D, 3,ALL
! Apply Load
F,2,FY,-300
! Solve
SOLVE
/POST1
! CivilFEM Postprocessor
! --------------------------------------------------
! Read results
~CFSET,,1,1
! Plot axial forces
~PLLSFOR,F,X
! Eurocode No.3 Check in Tension 受拉承载力检验
~CHKSTL,TENSION
! List Tension Check Results 列表显示受拉承载力检查结果
~PRSTL,DETAILED,BOTH,1
! Plot Tension Check Results
~PLLSSTL,CRT_TOT ! Eurocode No.3 Criterium (Must be < 1.00)
! Eurocode No.3 Check in Compression
~CHKSTL,COMPRESS
! List Compression Check Results
~PRSTL,DETAILED,BOTH,2
! Plot Compression Check Results
~PLLSSTL,CRT_TOT ! Nsd/Nc.Rd (Must be < 1.00)